program f90_FEMondoCH
    !２次元熱伝導解析
    implicit none
    integer::i,j,k,n,nnn,ia,ja,ne,it,k1,k2

    character(len=50)::ftinp         !温度履歴読み込みファイル
    character(len=100)::strcom       !書出用コメント
    integer::NODT                    !節点総数
    integer::NELT                    !要素総数
    integer::MATEL                   !材料種類数
    integer::KOT                     !温度指定節点数
    integer::KOC                     !熱伝達指定辺数
    integer::nod=4                   !1要素節点数
    integer::nhen=1                  !1節点自由度数
    integer::nt                      !全自由度（総節点数×１[１節点自由度]）
    integer::mm                      !温度固定点処理後自由度
    integer::ib                      !バンド幅
    integer,allocatable::kakom(:,:)  !要素構成接点番号
    real(8),allocatable::Ak(:)       !要素熱伝導率
    real(8),allocatable::Ac(:)       !要素比熱
    real(8),allocatable::Arho(:)     !要素単位堆積重量
    real(8),allocatable::Tk(:)       !要素最終温度上昇量
    real(8),allocatable::Al(:)       !要素発熱速度係数
    integer,allocatable::matno(:)    !材料種別No
    real(8),allocatable::wm(:,:)     !作業用材料物性記憶
    real(8),allocatable::x(:)        !節点x座標
    real(8),allocatable::y(:)        !節点y座標
    integer,allocatable::nokt(:)     !温度指定節点番号
    integer,allocatable::nekc(:,:)   !熱伝達境界要素・辺番号
    real(8),allocatable::alphac(:)   !指定辺熱伝達率
    real(8),allocatable::Tinp(:)     !指定温度入力
    real(8),allocatable::Tcin1(:)    !指定熱伝達境界温度入力（前回）
    real(8),allocatable::Tcin2(:)    !指定熱伝達境界温度入力（現在）
    real(8)::alpc                    !作業用熱伝達率
    real(8)::tc                      !作業用熱伝達境界温度
    integer::kchen                   !作業用熱伝達境界辺番号
    real(8)::dotq                    !作業用発熱率
    real(8),allocatable::tck1(:,:)   !全体剛性行列（前回）
    real(8),allocatable::tck2(:,:)   !全体剛性行列（現在）
    real(8),allocatable::rtck2(:,:)  !全体剛性行列（現在）拘束節点列保存
    real(8)::ck1(4,4)                !要素剛性行列（前回）
    real(8)::ck2(4,4)                !要素剛性行列（現在）
    real(8)::ht(4,4)                 !要素熱伝達行列
    real(8)::fq(4)                   !要素発熱率ベクトル
    real(8)::fc(4)                   !要素熱伝達ベクトル
    real(8),allocatable::tempe0(:)   !全体節点温度初期値
    real(8),allocatable::ftvec(:)    !全体熱流束ベクトル
    real(8),allocatable::tempe(:)    !全体節点温度ベクトル
    real(8),allocatable::reac(:)     !作業用節点温度ベクトル
    integer,allocatable::index(:)    !温度固定点処理用
    real(8)::delta                   !時間刻み
    real(8)::ttime                   !時刻
    integer::itmax                   !時刻歴ステップ数
    integer::nout                    !出力節点数
    integer,allocatable::noout(:)    !出力節点番号
    integer::ntout                   !全節点温度出力回数
    integer,allocatable::nntout(:)   !全節点温度出力ステップ
    real(8),allocatable::tempend(:,:)!出力用節点温度
    real(8)::fact0=1.0D-30           !0判定
    real(8)::elarea1
    real(8)::elarea2
    integer::io

    character::str*20
    character :: linebuf*1000
    character :: fmt1*200,fmt2*200
    real(4) :: t1,t2
    integer :: iv(1:8)
    character date*10,time1*20,time2*20,zone*10

    !時間計測開始
    call DATE_AND_TIME(date,time1,zone,iv)
    read(time1,*) t1
    !*****************************************************
    !データ入力
    !*****************************************************
    open(11,file='fnameR.csv',status='old')
    !--------------------------------------------------------------------------------------
    !書出用コメント入力
    !--------------------------------------------------------------------------------------
    read(11,'(a)') strcom
    !--------------------------------------------------------------------------------------
    !時刻歴読み込みファイル指定
    !--------------------------------------------------------------------------------------
    read(11,'(a)') ftinp
    !------------------------------------------------------------------------------------------
    !節点数，要素数，材料種類数,温度固定点数，熱伝達境界辺数，時間刻み
    !------------------------------------------------------------------------------------------
    read(11,*) NODT,NELT,MATEL,KOT,KOC,delta
    !------------------------------------------------------------------------------------------
    !配列寸法宣言
    !------------------------------------------------------------------------------------------
    nt=NODT*nhen
    allocate(kakom(1:NELT,1:4))
    allocate(Ak(1:NELT))
    allocate(Ac(1:NELT))
    allocate(Arho(1:NELT))
    allocate(Tk(1:NELT))
    allocate(Al(1:NELT))
    allocate(matno(1:NELT))
    allocate(wm(1:MATEL,1:5))
    allocate(x(1:NODT))
    allocate(y(1:NODT))
    allocate(nokt(1:KOT))
    allocate(nekc(1:KOC,1:2))
    allocate(alphac(1:KOC))
    allocate(Tinp(1:KOT))
    allocate(Tcin1(1:KOC))
    allocate(Tcin2(1:KOC))
    allocate(index(1:nt))
    allocate(tck1(1:nt,1:nt))
    allocate(tck2(1:nt,1:nt))
    allocate(rtck2(1:nt,1:KOT))
    allocate(tempe0(1:nt))
    allocate(tempe(1:nt))
    allocate(reac(1:nt))
    allocate(ftvec(1:nt))
    !------------------------------------------------------------------------------------------
    !材料特性（Ak,Ac,Arho,Tk,Al）
    !------------------------------------------------------------------------------------------
    do i=1,MATEL
        read(11,*) wm(i,1),wm(i,2),wm(i,3),wm(i,4),wm(i,5)
    end do
    !------------------------------------------------------------------------------------------
    !要素構成節点と材料種別（node-1,node-2,node-3,node-4,matno）
    !------------------------------------------------------------------------------------------
    do ne=1,NELT
        read(11,*) kakom(ne,1),kakom(ne,2),kakom(ne,3),kakom(ne,4),matno(ne)
        do i=1,MATEL
            if(i==matno(ne))then
                Ak(ne)  =wm(i,1)
                Ac(ne)  =wm(i,2)
                Arho(ne)=wm(i,3)
                Tk(ne)  =wm(i,4)
                Al(ne)  =wm(i,5)
            end if
        end do
    end do
    deallocate(wm)
    !------------------------------------------------------------------------------------------
    !節点座標（x,y）,初期節点温度
    !------------------------------------------------------------------------------------------
    do i=1,NODT
        read(11,*) x(i),y(i),tempe0(i)
    end do
    !------------------------------------------------------------------------------------------
    !温度指定節点番号
    !------------------------------------------------------------------------------------------
    if(0<KOT)then
        do i=1,KOT
            read(11,*) nokt(i)
        end do
    end if
    !------------------------------------------------------------------------------------------
    !熱伝達境界指定要素・辺番号・熱伝達率
    !------------------------------------------------------------------------------------------
    if(0<KOC)then
        do i=1,KOC
            read(11,*) nekc(i,1),nekc(i,2),alphac(i)
        end do
    end if
    !------------------------------------------------------------------------------------------
    !出力節点数,出力節点番号
    !------------------------------------------------------------------------------------------
    read(11,*) nout
    allocate(noout(1:nout))
    read(11,*) (noout(i),i=1,nout)
    !------------------------------------------------------------------------------------------
    !全節点温度出力回数,出力ステップ番号
    !------------------------------------------------------------------------------------------
    read(11,*) ntout
    if(0<ntout)then
        allocate(nntout(1:ntout))
        allocate(tempend(1:NODT,1:ntout))
        read(11,*) (nntout(i),i=1,ntout)
    end if
    close(11)

    !温度入力ファイル空読み：時刻ステップ数把握
    open(13,file=ftinp,status='old')
    read(13,'()')!コメント
    it=0
    do
        it=it+1
        read(13,'()',iostat=io) !ファイルの終わりに達したらexit
        if(io<0)exit
    end do
    itmax=it-1
    close(13)

    !*****************************************************
    !入力確認出力
    !*****************************************************
    fmt1="(i5,',',e15.7,',',e15.7,',',i2,',',e15.7)"    !節点入力値
    fmt2="(i5,',',i5,',',i5,',',i5,',',i5,',',i5,',',i5,',',e15.7,',',e15.7,',',e15.7,&
            ',',e15.7,',',e15.7,',',i5)"                  !要素特性

    open(12, file='fnameW.csv', status='replace')
    write(12,*) strcom
    write(12,*) 'NODT,NELT,MATEL,KOT,KOC,delta,nout,ntout,itmax'
        write(linebuf,*) NODT,',',NELT,',',MATEL,',',KOT,',',KOC,',',real(delta),',',nout,',',ntout,',',itmax
        call del_spaces(linebuf)
    write (12,'(a)') trim(linebuf)
    write(12,*) '*node characteristics'
    write(12,*) 'node,x,y,fix-T,Tinit'
    do i=1,NODT
        k=0
        if(0<KOT)then
            do j=1,KOT
                if(i==nokt(j))k=1
            end do
        end if
            write(linebuf,FMT=fmt1) i,x(i),y(i),k,tempe0(i)
            call del_spaces(linebuf)
        write (12,'(a)') trim(linebuf)
    end do
    write(12,*) '*element characteristics'
    write(12,*) 'element,node-1,node-2,node-3,node-4,k1,k2,Ak,Ac,Arho,Tk,Al,matno'
    do ne=1,NELT
        k1=0
        k2=0
        if(0<KOC)then
            k1=0
            k2=0
            do k=1,KOC
                if(ne==nekc(k,1))then
                    k1=1!熱伝達境界を有する要素（k1=1）
                    k2=nekc(k,2)!熱伝達境界の要素辺（1or2or3or4）
                end if
            end do
        end if
            write(linebuf,FMT=fmt2) ne,kakom(ne,1),kakom(ne,2),kakom(ne,3),kakom(ne,4),&
                k1,k2,Ak(ne),Ac(ne),Arho(ne),Tk(ne),Al(ne),matno(ne)
            call del_spaces(linebuf)
        write (12,'(a)') trim(linebuf)
    end do
    !要素面積確認と異常終了通知
    do ne=1,NELT
        i=kakom(ne,1)
        j=kakom(ne,2)
        k=kakom(ne,3)
        elarea1=0.5D0*((x(k)-x(j))*y(i)+(x(i)-x(k))*y(j)+(x(j)-x(i))*y(k))
        if(elarea1<fact0)then
            write(12,*) 'area of element is less or equal to 0'
            close(12)
            stop
        end if
        i=kakom(ne,1)
        j=kakom(ne,3)
        k=kakom(ne,4)
        elarea2=0.5D0*((x(k)-x(j))*y(i)+(x(i)-x(k))*y(j)+(x(j)-x(i))*y(k))
        if(elarea1<fact0)then
            write(12,*) 'area of element is less or equal to 0'
            close(12)
            stop
        end if
    end do
    close(12)

    !*****************************************************
    !メイン処理計算
    !*****************************************************
    !-----------------------------------------------------
    !全体行列クリア
    !-----------------------------------------------------
    do i=1,nt
        do j=1,nt
            tck1(i,j)=0.0D0
            tck2(i,j)=0.0D0
        end do
    end do
    !-----------------------------------------------------
    !全体行列組立
    !-----------------------------------------------------
    do ne=1,NELT
        Call STIFF(ne,kakom,x,y,Ak,Ac,Arho,ck1,ck2,delta,NELT,NODT)
        Call ASMAT(ne,nod,nhen,kakom,ck1,tck1,NELT,NODT)!前回剛性-0.5*[K]+1/dt*[C]
        Call ASMAT(ne,nod,nhen,kakom,ck2,tck2,NELT,NODT)!現在剛性+0.5*[K]+1/dt*[C]
        !熱伝達境界処理
        if(0<KOC)then
            do k=1,KOC
                if(ne==nekc(k,1))then
                    kchen=nekc(k,2)
                    alpc=alphac(k)
                    Call HTMAT(ne,kchen,kakom,x,y,alpc,ht,NELT,NODT)!熱伝達行列
                    do i=1,4
                        do j=1,4
                            ht(i,j)=0.5D0*ht(i,j)
                        end do
                    end do
                    Call ASMAT(ne,4,1,kakom,ht,tck2,NELT,NODT)!現在剛性
                    do i=1,4
                        do j=1,4
                            ht(i,j)=-ht(i,j)
                        end do
                    end do
                    Call ASMAT(ne,nod,nhen,kakom,ht,tck1,NELT,NODT)!前回剛性
                end if
            end do
        end if
    end do
    !-----------------------------------------------------
    !全体行列温度指定列要素保存
    !-----------------------------------------------------
    if(0<KOT)then
        do k=1,KOT
            do i=1,nt
                rtck2(i,k)=tck2(i,nokt(k))
            end do
        end do
    end if
    !-----------------------------------------------------
    !温度指定節点処理
    !-----------------------------------------------------
    do i=1,nt
        index(i)=i
    end do
    if(0<KOT)then
        do i=1,KOT
            n=nokt(i)
            index(n)=0
        end do
    end if
    mm=0
    do i=1,nt
        if(index(i)>0)then
            mm=mm+1
            index(mm)=i
        end if
    end do
    do i=1,mm
        ia=index(i)
        do j=1,mm
            ja=index(j)
            tck2(i,j)=tck2(ia,ja)
        end do
    end do

    !-----------------------------------------------------
    !バンド幅計算とフルマトリックスのバンド化記憶
    !-----------------------------------------------------
    ib=IBAND(mm,tck2,fact0,nt)
    Call BAND(mm,ib,tck2,nt)
    !-----------------------------------------------------
    !対角項確認と異常終了通知
    !-----------------------------------------------------
    do i=1,mm
        if(abs(tck2(i,1))<fact0)then
            open(12, file='fnameW.csv', access='append')
            write(12,*) 'diagonal value is less or equal to 0'
            close(12)
            stop
        end if
    end do
    !-----------------------------------------------------
    !コレスキー法（三角行列）
    !-----------------------------------------------------
    Call CHBAND10(mm,ib,tck2,nt)!三角行列

    !-----------------------------------------------------
    !時刻歴出力準備
    !-----------------------------------------------------
    !初期温度ベクトルセット
    do i=1,nt
        tempe(i)=tempe0(i)
    end do
    !熱伝達境界初期値設定
    if(0<KOC)then
        do k=1,KOC
            ne=nekc(k,1)
            select case(nekc(k,2))
                case (1)
                    ia=kakom(ne,1)
                    ja=kakom(ne,2)
                case (2)
                    ia=kakom(ne,2)
                    ja=kakom(ne,3)
                case (3)
                    ia=kakom(ne,3)
                    ja=kakom(ne,4)
                case (4)
                    ia=kakom(ne,4)
                    ja=kakom(ne,1)
            end select
            Tcin1(k)=0.5D0*(tempe(ia)+tempe(ja))
        end do
    end if

    !出力ファイルオープン
    open(12, file='fnameW.csv', access='append')
    write(12,*) '*Temperature records of selected nodes'
    !======================
    ttime=0.0D0
    it=0
    !======================
    linebuf="it,time"
    do i=1,nout
        write (str,'(",node-",i5)') noout(i)
        linebuf=trim(linebuf)//str
    end do
    call del_spaces(linebuf)
    write (12,'(a)') trim(linebuf)

    write (linebuf,'(i5)') it
    write (str,'(",",e15.7)') ttime
    linebuf=trim(linebuf)//str
    do i=1,nout
        write (str,'(",",e15.7)') tempe(noout(i))
        linebuf=trim(linebuf)//str
    end do
    call del_spaces(linebuf)
    write (12,'(a)') trim(linebuf)
    !*****************************************************
    !時刻歴計算（時刻歴入力ファイル：ftinpの最終行まで）
    !*****************************************************
    !指定温度時刻歴入力ファイルオープン
    open(13,file=ftinp,status='old')
    read(13,'()')!コメント
    nnn=0
    !************************
    do it=1,itmax
    !************************
        ttime=delta*real(it)
        !-----------------------------------------------------
        !指定温度時刻歴入力（指定温度はその都度入力）
        !-----------------------------------------------------
        !温度指定節点温度,熱伝達境界辺温度
        if(KOT==0.and.KOC==0)then
            read(13,*) i
        end if
        if(0<KOT.and.KOC==0)then
            read(13,*) i,(Tinp(k),k=1,KOT)
        end if
        if(0<KOT.and.0<KOC)then
            read(13,*) i,(Tinp(k),k=1,KOT),(Tcin2(k),k=1,KOC)
        end if
        if(KOT==0.and.0<KOC)then
            read(13,*) i,(Tcin2(k),k=1,KOC)
        end if
        !-----------------------------------------------------
        !熱流束ベクトル組立
        !-----------------------------------------------------
        !前回温度ベクトル
        do i=1,nt
            reac(i)=0.0D0
            do j=1,nt
                reac(i)=reac(i)+tck1(i,j)*tempe(j)
            end do
        end do
        !温度指定境界処理
        if(0<KOT)then
            do k=1,KOT
                do i=1,nt
                    reac(i)=reac(i)-Tinp(k)*rtck2(i,k)
                end do
            end do
        end if
        !熱伝達・発熱率ベクトル
        do i=1,nt
            ftvec(i)=0.0D0
        end do
        do ne=1,NELT
            !発熱率ベクトル
            dotq=Arho(ne)*Ac(ne)*Tk(ne)*Al(ne)*exp(-Al(ne)*ttime)
            dotq=dotq+Arho(ne)*Ac(ne)*Tk(ne)*Al(ne)*exp(-Al(ne)*(ttime-delta))
            dotq=0.5*dotq
            Call FQVEC(ne,kakom,x,y,dotq,fq,NELT,NODT)
            Call ASVEC(ne,nod,nhen,kakom,fq,ftvec,NELT,NODT)
            !熱伝達ベクトル
            if(0<KOC)then
                do k=1,KOC
                    if(ne==nekc(k,1))then
                        kchen=nekc(k,2)
                        alpc=alphac(k)
                        tc=0.5D0*(Tcin1(k)+Tcin2(k))
                        Call HTVEC(ne,kchen,kakom,x,y,alpc,tc,fc,NELT,NODT)
                        Call ASVEC(ne,nod,nhen,kakom,fc,ftvec,NELT,NODT)
                    end if
                end do
            end if
        end do
        !全体ベクトル
        do i=1,nt
            reac(i)=reac(i)+ftvec(i)
        end do
        !-----------------------------------------------------
        !温度指定節点処理
        !-----------------------------------------------------
        do i=1,mm
            ia=index(i)
            reac(i)=reac(ia)
        end do
        !-----------------------------------------------------
        !コレスキー法（前進消去・後退代入）
        !-----------------------------------------------------
        Call CHBAND11(mm,ib,tck2,reac,nt)
        !-----------------------------------------------------
        !現在温度算定
        !-----------------------------------------------------
        do i=1,nt
            tempe(i)=0.0D0
        end do
        do i=1,mm
            ia=index(i)
            tempe(ia)=reac(i)
        end do
        do k=1,KOT
            tempe(nokt(k))=Tinp(k)
        end do
        !-----------------------------------------------------
        !記憶更新
        !-----------------------------------------------------
        if(0<KOC)then
            do k=1,KOC
                Tcin1(k)=Tcin2(k)
            end do
        end if
        !-----------------------------------------------------
        !結果出力
        !-----------------------------------------------------
        write (linebuf,'(i5)') it
        write (str,'(",",e15.7)') ttime
        linebuf=trim(linebuf)//str
        do i=1,nout
            write (str,'(",",e15.7)') tempe(noout(i))
            linebuf=trim(linebuf)//str
        end do
        call del_spaces(linebuf)
        write (12,'(a)') trim(linebuf)
        !-----------------------------------------------------
        !節点温度保存
        !-----------------------------------------------------
        if(0<ntout)then
            do n=1,ntout
                if(it==nntout(n))then
                    nnn=nnn+1
                    do i=1,NODT
                        tempend(i,nnn)=tempe(i)
                    end do
                end if
            end do
        end if
    !************************
    end do
    !************************
    close(13)!指定温度時刻歴入力ファイルクローズ

    if(0<ntout)then
        !指定ステップ全節点温度出力
        write(12,*) '*Temperature of nodes for selected times'
        linebuf="Node,initial"
        do i=1,ntout
            write (str,'(",step-",i5)') nntout(i)
            linebuf=trim(linebuf)//str
        end do
        call del_spaces(linebuf)
        write (12,'(a)') trim(linebuf)

        do i=1,NODT
            write (linebuf,'(i5)') i
            write (str,'(",",e15.7)') tempe0(i)
            linebuf=trim(linebuf)//str
            do j=1,ntout
                write (str,'(",",e15.7)') tempend(i,j)
                linebuf=trim(linebuf)//str
            end do
            call del_spaces(linebuf)
            write (12,'(a)') trim(linebuf)
        end do

        !指定節点温度分布作成用出力
        write(12,*) '*Temperature distributions of selected nodes'
        linebuf="Node,x,y,initial"
        do i=1,ntout
        write (str,'(",step-",i5)') nntout(i)
        linebuf=trim(linebuf)//str
        end do
        call del_spaces(linebuf)
        write (12,'(a)') trim(linebuf)

        do i=1,nout
            k=noout(i)
            write (linebuf,'(i5)') k
            write (str,'(",",e15.7)') x(k)
            linebuf=trim(linebuf)//str
            write (str,'(",",e15.7)') y(k)
            linebuf=trim(linebuf)//str
            write (str,'(",",e15.7)') tempe0(k)
            linebuf=trim(linebuf)//str
            do j=1,ntout
                write (str,'(",",e15.7)') tempend(k,j)
                linebuf=trim(linebuf)//str
            end do
            call del_spaces(linebuf)
            write (12,'(a)') trim(linebuf)
        end do
    end if
    !-----------------------------------------------------
    !時間計測完了
    !-----------------------------------------------------
    !時間計測完了
    call DATE_AND_TIME(date,time2,zone,iv)
    read(time2,*) t2
    write(12,'("NODT=",i0," nt=",i0," mm=",i0," ib=",i0)') ,NODT,nt,mm,ib
    write(12,'("Calculation time=",f8.3,"(sec)")') t2-t1
    write(linebuf,*) 'Date_time=',iv(1),'.',iv(2),'.',iv(3),'_',iv(5),':',iv(6),':',iv(7)
    linebuf=trim(linebuf)//"_(gfortran)"
    call del_spaces(linebuf)
    write (12,'(a)') trim(linebuf)
    close(12)!出力ファイルクローズ

stop

Contains

    subroutine NMAT(ne,kakom,x,y,dnk,dnc,detJ,a,b,NELT,NODT)

        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,kakom(1:NELT,1:4)
        real(8),intent(in)::x(1:NODT),y(1:NODT)
        real(8),intent(in)::a,b
        real(8),intent(out)::detJ
        real(8),intent(out)::dnk(1:4,1:4),dnc(1:4,1:4)

        integer::i,j,k,l
        real(8)::J11,j12,J21,J22
        real(8)::dn1a,dn2a,dn3a,dn4a
        real(8)::dn1b,dn2b,dn3b,dn4b
        real(8)::dn1x,dn2x,dn3x,dn4x
        real(8)::dn1y,dn2y,dn3y,dn4y
        real(8)::nm1,nm2,nm3,nm4

        i=kakom(ne,1)
        j=kakom(ne,2)
        k=kakom(ne,3)
        l=kakom(ne,4)

        ![dN/da][dN/db]
        dn1a=-0.25D0*(1.0D0-b)
        dn2a= 0.25D0*(1.0D0-b)
        dn3a= 0.25D0*(1.0D0+b)
        dn4a=-0.25D0*(1.0D0+b)
        dn1b=-0.25D0*(1.0D0-a)
        dn2b=-0.25D0*(1.0D0+a)
        dn3b= 0.25D0*(1.0D0+a)
        dn4b= 0.25D0*(1.0D0-a)
        !Jacobiマトリックスとdet(J)
        J11=dn1a*x(i)+dn2a*x(j)+dn3a*x(k)+dn4a*x(l)
        J12=dn1a*y(i)+dn2a*y(j)+dn3a*y(k)+dn4a*y(l)
        J21=dn1b*x(i)+dn2b*x(j)+dn3b*x(k)+dn4b*x(l)
        J22=dn1b*y(i)+dn2b*y(j)+dn3b*y(k)+dn4b*y(l)
        detJ=J11*J22-J12*J21
        ![dN/dx][dN/dy]
        dn1x=( J22*dn1a-J12*dn1b)/detJ
        dn2x=( J22*dn2a-J12*dn2b)/detJ
        dn3x=( J22*dn3a-J12*dn3b)/detJ
        dn4x=( J22*dn4a-J12*dn4b)/detJ
        dn1y=(-J21*dn1a+J11*dn1b)/detJ
        dn2y=(-J21*dn2a+J11*dn2b)/detJ
        dn3y=(-J21*dn3a+J11*dn3b)/detJ
        dn4y=(-J21*dn4a+J11*dn4b)/detJ
        ![N]行列要素
        nm1=0.25D0*(1.0D0-a)*(1.0D0-b)
        nm2=0.25D0*(1.0D0+a)*(1.0D0-b)
        nm3=0.25D0*(1.0D0+a)*(1.0D0+b)
        nm4=0.25D0*(1.0D0-a)*(1.0D0+b)

        dnk(1,1)=dn1x*dn1x+dn1y*dn1y
        dnk(1,2)=dn1x*dn2x+dn1y*dn2y
        dnk(1,3)=dn1x*dn3x+dn1y*dn3y
        dnk(1,4)=dn1x*dn4x+dn1y*dn4y
        dnk(2,1)=dn2x*dn1x+dn2y*dn1y
        dnk(2,2)=dn2x*dn2x+dn2y*dn2y
        dnk(2,3)=dn2x*dn3x+dn2y*dn3y
        dnk(2,4)=dn2x*dn4x+dn2y*dn4y
        dnk(3,1)=dn3x*dn1x+dn3y*dn1y
        dnk(3,2)=dn3x*dn2x+dn3y*dn2y
        dnk(3,3)=dn3x*dn3x+dn3y*dn3y
        dnk(3,4)=dn3x*dn4x+dn3y*dn4y
        dnk(4,1)=dn4x*dn1x+dn4y*dn1y
        dnk(4,2)=dn4x*dn2x+dn4y*dn2y
        dnk(4,3)=dn4x*dn3x+dn4y*dn3y
        dnk(4,4)=dn4x*dn4x+dn4y*dn4y

        dnc(1,1)=nm1*nm1
        dnc(1,2)=nm1*nm2
        dnc(1,3)=nm1*nm3
        dnc(1,4)=nm1*nm4
        dnc(2,1)=nm2*nm1
        dnc(2,2)=nm2*nm2
        dnc(2,3)=nm2*nm3
        dnc(2,4)=nm2*nm4
        dnc(3,1)=nm3*nm1
        dnc(3,2)=nm3*nm2
        dnc(3,3)=nm3*nm3
        dnc(3,4)=nm3*nm4
        dnc(4,1)=nm4*nm1
        dnc(4,2)=nm4*nm2
        dnc(4,3)=nm4*nm3
        dnc(4,4)=nm4*nm4

    end subroutine NMAT


    subroutine IPOINT4(kk,a,b)
        integer,intent(in)::kk
        real(8),intent(out)::a,b

        !Gauss積分点
        select case (kk)
            case (1)
                a=-0.5773502692D0
                b=-0.5773502692D0
            case (2)
                a= 0.5773502692D0
                b=-0.5773502692D0
            case (3)
                a= 0.5773502692D0
                b= 0.5773502692D0
            case (4)
                a=-0.5773502692D0
                b= 0.5773502692D0
        end select
    end subroutine IPOINT4


    subroutine STIFF(ne,kakom,x,y,Ak,Ac,Arho,ck1,ck2,delta,NELT,NODT)
        !要素剛性行列
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,kakom(1:NELT,1:4)
        real(8),intent(in)::x(1:NODT),y(1:NODT)
        real(8),intent(in)::Ak(1:NELT),Ac(1:NELT),Arho(1:NELT)
        real(8),intent(in)::delta
        real(8),intent(out)::ck1(1:4,1:4),ck2(1:4,1:4)

        integer::kk,i,j
        real(8)::dnk(1:4,1:4),dnc(1:4,1:4),ww1(1:4,1:4),ww2(1:4,1:4)
        real(8)::detJ,a,b

        do i=1,4
            do j=1,4
                ww1(i,j)=0.0D0
                ww2(i,j)=0.0D0
                ck1(i,j)=0.0D0
                ck2(i,j)=0.0D0
            end do
        end do
        do kk=1,4
            Call IPOINT4(kk,a,b)
            Call NMAT(ne,kakom,x,y,dnk,dnc,detJ,a,b,NELT,NODT)
            do i=1,4
                do j=1,4
                    ww1(i,j)=ww1(i,j)+Ak(ne)*dnk(i,j)*detJ
                    ww2(i,j)=ww2(i,j)+Arho(ne)*Ac(ne)*dnc(i,j)*detJ
                end do
            end do
        end do
        do i=1,4
            do j=1,4
                ck1(i,j)=-0.5D0*ww1(i,j)+1.0D0/delta*ww2(i,j)
                ck2(i,j)=+0.5D0*ww1(i,j)+1.0D0/delta*ww2(i,j)
            end do
        end do

    end subroutine STIFF


    subroutine LPOINT4(kk,kchen,a,b)
        !要素辺上積分におけるGauss積分点
        integer,intent(in)::kk,kchen
        real(8),intent(out)::a,b

        select case(kchen)
            case(1)
                b=-1.0
               if(kk==1)a=-0.5773502692D0
               if(kk==2)a= 0.5773502692D0
            case(2)
               a=1.0
               if(kk==1)b=-0.5773502692D0
               if(kk==2)b= 0.5773502692D0
            case(3)
               b=1.0
               if(kk==1)a=-0.5773502692D0
               if(kk==2)a= 0.5773502692D0
            case(4)
                a=-1.0
                if(kk==1)b=-0.5773502692D0
                if(kk==2)b= 0.5773502692D0
        end select

    end subroutine LPOINT4


    subroutine HTMAT(ne,kchen,kakom,x,y,alpc,ht,NELT,NODT)
        !要素熱伝達マトリックス
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,kchen,kakom(1:NELT,1:4)
        real(8),intent(in)::x(1:NODT),y(1:NODT)
        real(8),intent(in)::alpc
        real(8),intent(out)::ht(1:4,1:4)

        integer::i,j,kk
        real(8)::a,b,s,vn(1:4)

        select case (kchen)
            case(1)
                i=kakom(ne,1)
                j=kakom(ne,2)
            case(2)
                i=kakom(ne,2)
                j=kakom(ne,3)
            case(3)
                i=kakom(ne,3)
                j=kakom(ne,4)
            case(4)
                i=kakom(ne,4)
                j=kakom(ne,1)
        end select
        s=sqrt((x(j)-x(i))**2.0D0+(y(j)-y(i))**2.0D0)

        do i=1,4
            do j=1,4
                ht(i,j)=0.0D0
            end do
        end do
        do kk=1,2
            Call LPOINT4(kk,kchen,a,b)
            ![N]行列要素
            vn(1)=0.25D0*(1.0D0-a)*(1.0D0-b)
            vn(2)=0.25D0*(1.0D0+a)*(1.0D0-b)
            vn(3)=0.25D0*(1.0D0+a)*(1.0D0+b)
            vn(4)=0.25D0*(1.0D0-a)*(1.0D0+b)
            do i=1,4
                do j=1,4
                    ht(i,j)=ht(i,j)+0.5D0*s*alpc*vn(i)*vn(j)
                end do
            end do
        end do

    end subroutine HTMAT


    subroutine FQVEC(ne,kakom,x,y,dotq,fq,NELT,NODT)
        !発熱率ベクトル
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,kakom(1:NELT,1:4)
        real(8),intent(in)::x(1:NODT),y(1:NODT)
        real(8),intent(in)::dotq
        real(8),intent(out)::fq(1:4)

        integer::i,j,k,l,kk
        real(8)::detJ,a,b,vn(1:4)
        real(8)::J11,J12,J21,J22
        real(8)::dn1a,dn2a,dn3a,dn4a
        real(8)::dn1b,dn2b,dn3b,dn4b

        do i=1,4
            fq(i)=0.0D0
        end do
        do kk=1,4
            Call IPOINT4(kk,a,b)
            i=kakom(ne,1)
            j=kakom(ne,2)
            k=kakom(ne,3)
            l=kakom(ne,4)
            ![dN/da][dN/db]
            dn1a=-0.25D0*(1.0D0-b)
            dn2a= 0.25D0*(1.0D0-b)
            dn3a= 0.25D0*(1.0D0+b)
            dn4a=-0.25D0*(1.0D0+b)
            dn1b=-0.25D0*(1.0D0-a)
            dn2b=-0.25D0*(1.0D0+a)
            dn3b= 0.25D0*(1.0D0+a)
            dn4b= 0.25D0*(1.0D0-a)
            !Jacobiマトリックスとdet(J)
            J11=dn1a*x(i)+dn2a*x(j)+dn3a*x(k)+dn4a*x(l)
            J12=dn1a*y(i)+dn2a*y(j)+dn3a*y(k)+dn4a*y(l)
            J21=dn1b*x(i)+dn2b*x(j)+dn3b*x(k)+dn4b*x(l)
            J22=dn1b*y(i)+dn2b*y(j)+dn3b*y(k)+dn4b*y(l)
            detJ=J11*J22-J12*J21
            ![N]行列要素
            vn(1)=0.25D0*(1.0D0-a)*(1.0D0-b)
            vn(2)=0.25D0*(1.0D0+a)*(1.0D0-b)
            vn(3)=0.25D0*(1.0D0+a)*(1.0D0+b)
            vn(4)=0.25D0*(1.0D0-a)*(1.0D0+b)
            do i=1,4
                fq(i)=fq(i)+dotq*vn(i)*detJ
            end do
        end do

    end subroutine FQVEC


    subroutine HTVEC(ne,kchen,kakom,x,y,alpc,tc,fc,NELT,NODT)
        !熱伝達ベクトル
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,kchen,kakom(1:NELT,1:4)
        real(8),intent(in)::x(1:NODT),y(1:NODT)
        real(8),intent(in)::alpc,tc
        real(8),intent(out)::fc(1:4)

        integer::i,j,kk
        real(8)::a,b,vn(1:4),s

        select case (kchen)
            case(1)
                i=kakom(ne,1)
                j=kakom(ne,2)
            case(2)
                i=kakom(ne,2)
                j=kakom(ne,3)
            case(3)
                i=kakom(ne,3)
                j=kakom(ne,4)
            case(4)
                i=kakom(ne,4)
                j=kakom(ne,1)
        end select
        s=sqrt((x(j)-x(i))**2.0D0+(y(j)-y(i))**2.0D0)

        do i=1,4
            fc(i)=0.0D0
        end do
        do kk=1,2
            Call LPOINT4(kk,kchen,a,b)
            ![N]行列要素
            vn(1)=0.25D0*(1.0D0-a)*(1.0D0-b)
            vn(2)=0.25D0*(1.0D0+a)*(1.0D0-b)
            vn(3)=0.25D0*(1.0D0+a)*(1.0D0+b)
            vn(4)=0.25D0*(1.0D0-a)*(1.0D0+b)
            do i=1,4
                fc(i)=fc(i)+0.5D0*s*alpc*tc*vn(i)
            end do
        end do

    end subroutine HTVEC


    subroutine ASVEC(ne,nod,nhen,kakom,fevec,ftvec,NELT,NODT)
        !荷重ベクトル組立(nod：1要素節点数，nhen：1節点の自由度)
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,nod,nhen
        integer,intent(in)::kakom(1:NELT,1:nod)
        real(8),intent(in)::fevec(1:nod*nhen)
        real(8),intent(inout)::ftvec(1:NODT*nhen)

        integer :: i,k,ki,ks,kik,ksk

        do i=1,nod
            ki=(kakom(ne,i)-1)*nhen
            ks=(i-1)*nhen
            do k=1,nhen
                kik=ki+k
                ksk=ks+k
                ftvec(kik)=ftvec(kik)+fevec(ksk)
            end do
        end do
    end subroutine ASVEC


    subroutine ASMAT(ne,nod,nhen,kakom,sm,tsm,NELT,NODT)
        !剛性行列組立(nod：1要素節点数，nhen：1節点の自由度)
        integer,intent(in)::NELT,NODT
        integer,intent(in)::ne,nod,nhen
        integer,intent(in)::kakom(1:NELT,1:nod)
        real(8),intent(in)::sm(1:nod*nhen,1:nod*nhen)
        real(8),intent(inout)::tsm(1:NODT*nhen,1:NODT*nhen)

        integer :: i,j,k,l,ki,kj,ks,js,kik,kjl,ksk,jsl

        do i=1,nod
            do j=1,nod
                ki=(kakom(ne,i)-1)*nhen
                kj=(kakom(ne,j)-1)*nhen
                ks=(i-1)*nhen
                js=(j-1)*nhen
                do k=1,nhen
                    do l=1,nhen
                        kik=ki+k
                        kjl=kj+l
                        ksk=ks+k
                        jsl=js+l
                        tsm(kik,kjl)=tsm(kik,kjl)+sm(ksk,jsl)
                    end do
                end do
            end do
        end do
    end subroutine ASMAT


    subroutine CHBAND10(n1,m1,array,nt)
        integer,intent(in)::n1,m1,nt
        real(8),intent(inout)::array(1:nt,1:nt)
        integer :: i,j,k,mm,mn
        real(8) :: z

        array(1,1)=sqrt(array(1,1))
        do j=2,m1
            array(1,j)=array(1,j)/array(1,1)
        end do
        do i=2,n1
            if(n1-i+1>m1)then
                mm=m1
            else
                mm=n1-i+1
            end if
            do j=1,mm
                z=array(i,j)
                if(j/=m1)then
                    if(m1-j+1<i)then
                        mn=m1-j+1
                    else
                        mn=i
                    end if
                    do k=2,mn
                        z=z-array(i-k+1,k)*array(i-k+1,j+k-1)
                    end do
                    if(j>1)then
                        array(i,j)=z/array(i,1)
                    else
                        array(i,1)=sqrt(z)
                    end if
                else
                    array(i,j)=z/array(i,1)
                end if
            end do
        end do
    end subroutine CHBAND10


    subroutine CHBAND11(n1,m1,array,vector,nt)
        integer,intent(in)::n1,m1,nt
        real(8),intent(in)::array(1:nt,1:nt)
        real(8),intent(out)::vector(nt)
        integer :: i,j,mm
        real(8) :: z

        vector(1)=vector(1)/array(1,1)
        do i=2,n1
            z=vector(i)
            if(i>m1)then
                mm=m1
            else
                mm=i
            end if
            do j=2,mm
                z=z-array(i-j+1,j)*vector(i-j+1)
            end do
            vector(i)=z/array(i,1)
        end do

        vector(n1)=vector(n1)/array(n1,1)
        do i=n1-1,1,-1
            z=vector(i)
            do j=2,m1
                if(i+j-1>n1)exit
                z=z-array(i,j)*vector(i+j-1)
            end do
            vector(i)=z/array(i,1)
        end do
    end subroutine CHBAND11


    integer function IBAND(mm,array,fact0,nt)
        integer,intent(in)::mm,nt
        real(8),intent(in)::array(1:nt,1:nt),fact0
        integer :: i,j
        !-----------------------------------------------------
        !バンド幅計算
        !-----------------------------------------------------
        IBAND=1
        do i=1,mm-1
            do j=mm,i+1,-1
                if(fact0<=abs(array(i,j)))exit
            end do
            if(IBAND<=j-i+1)IBAND=j-i+1
        end do
        if(mm<IBAND)IBAND=mm
    end function IBAND


    subroutine BAND(mm,ib,array,nt)
        integer,intent(in)::mm,ib,nt
        real(8),intent(inout)::array(1:nt,1:nt)
        integer :: i,j,mn
        real(8) :: work(1:nt)
        !-----------------------------------------------------
        !フルマトリックスのバンド化記憶
        !-----------------------------------------------------
        do i=2,mm
            if(i+ib-1<mm)then
                mn=ib
            else
                mn=mm-i+1
            end if
            do j=1,ib
                work(j)=0.0D0
            end do
            do k=1,mn
                work(k)=array(i,i+k-1)
            end do
            do j=1,ib
                array(i,j)=work(j)
            end do
        end do
    end subroutine BAND


    subroutine del_spaces(s)
        character (*), intent (inout) :: s
        character (len=len(s)) tmp
        integer i, j
        j = 1
        do i = 1, len(s)
            if (s(i:i)==' ') cycle
            tmp(j:j) = s(i:i)
            j = j + 1
        end do
        s = tmp(1:j-1)
    end subroutine del_spaces


end program f90_FEMondoCH