rem ============================================
rem Drawing by GMT (response spectrum)
rem ============================================
set range=0.01/10/10/10000
set scale=12l/10l
set xga=g3a1
set yga=g3a1
set xlabel="Period (sec)"
set ylabel="Response acceleration (gal)"
rem **************************************************************************
rem * set range=0.01/10/10/10000
rem *     x軸範囲を0.01〜10，y軸範囲を10〜19999に設定
rem * set scale=12l/10l
rem *     x軸を長さ12cmの対数軸，y軸を長さ10cmの対数軸に設定
rem * set xga=g3a1                             x軸目盛を設定
rem * set yga=g3a1                             y軸目盛を設定
rem * set xlabel="Period (sec)"                x軸ラベルを設定
rem * set ylabel="Response acceleration (gal)" y軸ラベルを設定
rem **************************************************************************
gmtset ANOT_FONT_SIZE 12
gmtset LABEL_FONT_SIZE 12
gmtset TICK_LENGTH 0c
rem ============================================
rem Drawing of TCGH16
rem ============================================
set inpl=inp_legend_t.txt
set inp_1=dat_spc_TCGH16_EW2.csv
set inp_2=dat_spc_TCGH16_NS2.csv
set inp_3=dat_spc_TCGH16_UD2.csv
set fig_out=fig_spc_t.eps
rem **************************************************************************
rem * set inpl=inp_legend_t.txt         凡例作成用入力ファイル
rem * set inp_1=dat_spc_TCGH16_EW2.csv  入力ファイル名1
rem * set inp_2=dat_spc_TCGH16_NS2.csv  入力ファイル名2
rem * set inp_3=dat_spc_TCGH16_UD2.csv  入力ファイル名3
rem *     ここでは3本の加速度応答スペクトルを描画するので3入力ファイルを指定
rem * set fig_out=fig_spc_t.eps         出力画像ファイル名
rem **************************************************************************
rem -------------------------------
rem Making of batch file for legend
rem -------------------------------
gawk -f awk_klegend.awk %inpl% > legend.bat
rem **************************************************************************
rem * gawk -f awk_klegend.awk %inpl% > legend.bat
rem *     凡例出力用バッチファイルの作成(awkスクリプト実行)
rem **************************************************************************
rem -------------------------------
rem Plotting
rem -------------------------------
psbasemap -R%range% -JX%scale% -B%xga%:%xlabel%:/%yga%:%ylabel%:WSen -P -X5 -Y6 -K > %fig_out%
gawk "BEGIN{FS=\",\"}{if(3<NR)print $1,$2}" %inp_1% | psxy -R -J -B -W5        -P -O -K >> %fig_out%
gawk "BEGIN{FS=\",\"}{if(3<NR)print $1,$2}" %inp_2% | psxy -R -J -B -W5t10_5:0 -P -O -K >> %fig_out%
gawk "BEGIN{FS=\",\"}{if(3<NR)print $1,$2}" %inp_3% | psxy -R -J -B -W5t5_5:0  -P -O -K >> %fig_out%
rem **************************************************************************
rem * gawkスクリプトを実行し，それぞれの入力ファイルより，
rem * 4行目以降の1列目と2列目のpsxyに送り込みプロット
rem * BEGIN{FS=\",\"} gawkでデータ区切り文字を「,」に設定
rem * -W5        太さ5ptの実線
rem * -W5t10_5:0 太さ5ptの鎖線
rem * -W5t5_5:0  太さ5ptの点線
rem **************************************************************************
echo 0 1.02 10 0 0 BL Damping factor h=0.05 | pstext -R0/1/0/1 -JX12/10 -N -P -O -K >> %fig_out%
rem **************************************************************************
rem * グラフ左上にテキスト(Damping factor h=0.05)を書き込む
rem * -R0/1/0/1  x軸範囲(0/1)・y軸範囲(0/1)を再定義
rem * -JX12/10   x軸長さ(12cm)・y軸長さ(10cm)を普通軸で再定義
rem **************************************************************************
rem -------------------------------
rem Drawing of legend
rem -------------------------------
call legend.bat



rem ============================================
rem Delete of work files
rem ============================================
del .gmt*
del _*.*

rem ============================================
rem Releasing of the set variables
rem ============================================
set range=
set scale=
set xga=
set yga=
set xlabel=
set ylabel=
set inpl=
set inp_1=
set inp_2=
set inp_3=
set fig_out=