reset
set terminal postscript eps enhanced color font "Arial" 14
set output "fig_gpl_tsd_Q.eps"
set origin 0,0
set size ratio 0.5
set title "Discharge at Kamifukushima gauging station in Tonegawa river (2008)"
set datafile separator ","
set xdata time
set timefmt "%Y/%m/%d"
set format x "%d-%b"
set format y "%.0f"
set xtics offset 0,-3.0 rotate by 90
set ytics
set xlabel "Date (2008)" offset 0,-1.5
set ylabel "Discharge (m^3/s)" 
set grid
set xrange ["2008/01/01":"2008/12/31"]
set x2range [1:365]
set yrange [0:1000]
#
set object rect from graph 0.74,graph 0.50 to graph 0.98,graph 0.95 fs solid 1.0 fc rgb "#ffffe0"
set label "CA"      at graph 0.75,graph 0.900 left textcolor rgb "red"
set label "Max."    at graph 0.75,graph 0.850 left textcolor rgb "red"
set label "35 day"  at graph 0.75,graph 0.800 left textcolor rgb "red"
set label "95 day"  at graph 0.75,graph 0.750 left textcolor rgb "red"
set label "185 day" at graph 0.75,graph 0.700 left textcolor rgb "red"
set label "275 day" at graph 0.75,graph 0.650 left textcolor rgb "red"
set label "355 day" at graph 0.75,graph 0.600 left textcolor rgb "red"
set label "Min."    at graph 0.75,graph 0.550 left textcolor rgb "red"
set label "3661 km^2"    at graph 0.97,graph 0.900 right textcolor rgb "red"
set label "955.33 m^3/s" at graph 0.97,graph 0.850 right textcolor rgb "red"
set label "277.39 m^3/s" at graph 0.97,graph 0.800 right textcolor rgb "red"
set label "177.75 m^3/s" at graph 0.97,graph 0.750 right textcolor rgb "red"
set label "100.07 m^3/s" at graph 0.97,graph 0.700 right textcolor rgb "red"
set label  "69.65 m^3/s" at graph 0.97,graph 0.650 right textcolor rgb "red"
set label  "54.38 m^3/s" at graph 0.97,graph 0.600 right textcolor rgb "red"
set label  "50.53 m^3/s" at graph 0.97,graph 0.550 right textcolor rgb "red"
#
set key left top
set key box
set key width -2
plot \
"inp_QKF2008.txt" using 1:2 axes x1y1 with lines linetype 1 linewidth 2 linecolor rgb "blue" title "Discharge", \
"inp_sort.txt"    using 1:2 axes x2y1 with lines linetype 1 linewidth 2 linecolor rgb "red" title "Duration curve", \
"-" axes x2y1 with points pointtype 7 pointsize 1.5 linecolor rgb "red" notitle, \
"-" axes x2y1 with points pointtype 7 pointsize 1.0 linecolor rgb "white" notitle
  1,955.33
 35,277.39
 95,177.75
185,100.07
275, 69.65
355, 54.38
365, 50.53
e
  1,955.33
 35,277.39
 95,177.75
185,100.07
275, 69.65
355, 54.38
365, 50.53
e
#
#
quit