Option Explicit On
Option Strict On
Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ToolStripLabel1.Text = "バンド幅"
        ToolStripTextBox1.Text = "0.4"
    End Sub


    Private Sub ToolStripButton1_Click_1(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ToolStripButton1.Click
        Call main()
        MessageBox.Show("処理完了", "完了通知")
    End Sub

    Private Sub main()
        'フーリエスペクトル比算定
        '分子・分母にするデータのサンプリングピッチ・データ数は等しくとる
        Dim nnn As Integer
        Dim i As Integer
        Dim fnameR As String = ""
        Dim fnameW As String = ""
        Dim sr As System.IO.StreamReader
        Dim sw As System.IO.StreamWriter
        Dim dat As String
        Dim sbuf() As String
        Dim delim() As Char = {","c}

        Dim strcom1() As String
        Dim strcom2() As String
        Dim rn1() As String
        Dim rn2() As String
        Dim wn0() As String
        Dim slog() As String
        Dim ncase As Integer
        Dim icase As Integer

        Dim dt As Double
        Dim nn As Integer
        Dim nd As Integer
        Dim fs01() As Double '分子原スペクトル
        Dim fs02() As Double '分子原スペクトル
        Dim fsp1() As Double '分子平滑化スペクトル
        Dim fsp2() As Double '分母平滑化スペクトル
        Dim fspr() As Double '平滑化スペクトル比
        Dim fq() As Double '振動数
        Dim band As Double

        Dim ndmax As Integer = CInt(2 ^ 16)
        ReDim fs01(ndmax)
        ReDim fs02(ndmax)
        ReDim fsp1(ndmax)
        ReDim fsp2(ndmax)
        ReDim fq(ndmax)

        For i = 0 To ndmax
            fs01(i) = 0.0
            fs02(i) = 0.0
            fsp1(i) = 0.0
            fsp2(i) = 0.0
            fq(i) = 0.0
        Next i

        '平滑化バンド幅設定
        band = CDbl(ToolStripTextBox1.Text)

        '入出力ファイル読み込み
        OpenFileDialog1.InitialDirectory = My.Computer.FileSystem.CurrentDirectory
        If OpenFileDialog1.ShowDialog() = Windows.Forms.DialogResult.OK Then fnameR = OpenFileDialog1.FileName
        sr = New System.IO.StreamReader(fnameR, System.Text.Encoding.Default)
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : ncase = CInt(sbuf(0))
        ReDim strcom1(ncase - 1)
        ReDim strcom2(ncase - 1)
        ReDim rn1(ncase - 1)
        ReDim rn2(ncase - 1)
        ReDim wn0(ncase - 1)
        ReDim slog(ncase - 1)
        For icase = 1 To ncase
            dat = sr.ReadLine() : sbuf = dat.Split(delim)
            strcom1(icase - 1) = sbuf(0)
            strcom2(icase - 1) = sbuf(1)
            rn1(icase - 1) = sbuf(2)
            rn2(icase - 1) = sbuf(3)
            wn0(icase - 1) = sbuf(4)
            slog(icase - 1) = sbuf(5)
        Next icase
        sr.Close()

        For icase = 1 To ncase

            For nnn = 1 To 2
                '原波形読み込みと平滑化フーリエスペクトル計算
                Select Case nnn
                    Case 1
                        fnameR = System.IO.Path.GetDirectoryName(fnameR) & "\" & rn1(icase - 1)
                        Call CALFSP(fnameR, dt, nn, band, fs01, fsp1)
                    Case 2
                        fnameR = System.IO.Path.GetDirectoryName(fnameR) & "\" & rn2(icase - 1)
                        Call CALFSP(fnameR, dt, nn, band, fs02, fsp2)
                End Select
            Next nnn
            'スペクトル比計算
            nd = CInt(nn / 2)
            ReDim fspr(nd)
            For i = 0 To nd
                fspr(i) = fsp1(i) / fsp2(i)
            Next i
            '振動数設定
            For i = 0 To nd
                fq(i) = CDbl(i) / CDbl(nn) / dt '振動数
            Next i

            '結果書き出し
            fnameW = System.IO.Path.GetDirectoryName(fnameR) & "\" & wn0(icase - 1) & ".csv"
            sw = New System.IO.StreamWriter(fnameW, False, System.Text.Encoding.Default)
            dat = "バンド幅" & "," & band.ToString : sw.WriteLine(dat)
            dat = "データ数" & "," & (nd + 1).ToString : sw.WriteLine(dat)
            dat = "振動数,分子原SP,分母原SP,平滑化分子SP,平滑化分母SP,平滑化SP比" : sw.WriteLine(dat)
            For i = 0 To nd
                dat = fq(i).ToString("0.000")
                dat = dat & "," & fs01(i).ToString("0.000")
                dat = dat & "," & fs02(i).ToString("0.000")
                dat = dat & "," & fsp1(i).ToString("0.000")
                dat = dat & "," & fsp2(i).ToString("0.000")
                dat = dat & "," & fspr(i).ToString("0.000")
                sw.WriteLine(dat)
            Next i
            sw.Close()

            'Call PLTCTL(icase, nn, dt, fq, fs01, fs02, fsp1, fsp2, fspr, wn0, strcom1, strcom2, slog, fnameR)

        Next icase

    End Sub


    Private Sub CALFSP(ByVal fnameR As String, ByRef dt As Double, ByRef nn As Integer, _
                       ByVal band As Double, ByRef fs0() As Double, ByRef fsp() As Double)
        Dim sr As System.IO.StreamReader
        Dim dat As String
        Dim sbuf() As String
        Dim delim() As Char = {","c}
        Dim ndata As Integer
        Dim nd As Integer
        Dim ddy() As Double
        Dim dy() As Double
        Dim y() As Double
        Dim ddymax As Double
        Dim dymax As Double
        Dim ymax As Double
        Dim xr() As Double
        Dim xi() As Double
        Dim df As Double

        '原波形読み込み
        sr = New System.IO.StreamReader(fnameR, System.Text.Encoding.Default)
        dat = sr.ReadLine() : sbuf = dat.Split(delim)
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : dt = CDbl(sbuf(1))
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : ndata = CInt(sbuf(1))
        nn = 2
        Do
            nn = nn * 2
        Loop While nn < ndata
        nd = CInt(nn / 2)
        ReDim ddy(nn - 1)
        ReDim dy(nn - 1)
        ReDim y(nn - 1)
        ReDim xr(nn - 1)
        ReDim xi(nn - 1)

        For i = 1 To nn 'データ数を2の階乗にセット
            ddy(i - 1) = 0.0 : dy(i - 1) = 0.0 : y(i - 1) = 0.0
        Next
        For i = 1 To ndata
            dat = sr.ReadLine() : sbuf = dat.Split(delim) : ddy(i - 1) = CDbl(sbuf(0))
        Next i
        sr.Close()

        '平滑化フーリエスペクトル作成
        Call IACC(ndata, dt, ddy, dy, y, ddymax, dymax, ymax) '数値積分
        Call CRAC(ndata, dt, ddy, dy, y, ddymax, dymax, ymax) '基線補正
        For i = 1 To nn
            xr(i - 1) = ddy(i - 1)
            xi(i - 1) = 0.0
        Next i
        Call FFT(nn, xr, xi) 'フーリエ変換
        For i = 1 To nn '戻り値をデータ数で除す
            xr(i - 1) = xr(i - 1) / CDbl(nn)
            xi(i - 1) = xi(i - 1) / CDbl(nn)
        Next i
        For i = 1 To nd + 1
            fs0(i - 1) = dt * CDbl(nn) * Math.Sqrt(xr(i - 1) * xr(i - 1) + xi(i - 1) * xi(i - 1)) '分子フーリエスペクトル
            fsp(i - 1) = fs0(i - 1)
        Next i
        df = 1.0 / dt / CDbl(nn)
        Call SWIN(nn, fsp, df, band) 'スペクトル平滑化

    End Sub


    Private Sub PLTCTL(ByVal icase As Integer, ByVal nn As Integer, ByVal dt As Double, _
                       ByRef fq() As Double, ByRef fs01() As Double, ByRef fs02() As Double, _
                       ByRef fsp1() As Double, ByRef fsp2() As Double, ByRef fspr() As Double, _
                       ByRef wn0() As String, ByRef strcom1() As String, ByRef strcom2() As String, _
                       ByRef slog() As String, ByVal fnameR As String)

        '作図
        Dim fnameD As String = ""
        Dim jj As Integer
        Dim kpt As Integer
        Dim sxjiku As String = ""
        Dim syjiku As String = ""
        Dim HSIZE As Integer = 1000
        Dim DHL As Integer = 100
        Dim DHR As Integer = 20
        Dim VSIZE As Integer = 500
        Dim DVL As Integer = 100
        Dim DVU As Integer = 70
        Dim kxi0 As Integer
        Dim kxf0 As Integer
        Dim kyi0 As Integer
        Dim kyf0 As Integer
        Dim figxmin As Double
        Dim figxmax As Double
        Dim figdx As Double
        Dim figymin As Double
        Dim figymax As Double
        Dim figdy As Double
        Dim nd As Integer
        Dim datax() As Double
        Dim datay() As Double
        Dim df As Double
        Dim band As Double
        Dim fsmax As Double
        Dim comR As String = ""
        Dim g As Graphics
        Dim bmp As Bitmap

        nd = CInt(nn / 2)
        ReDim datax(nd)
        ReDim datay(nd)

        kxi0 = DHL : kxf0 = HSIZE - DHR
        kyi0 = DVU : kyf0 = VSIZE - DVL
        Select Case slog(icase - 1)
            Case "N"
                figxmin = 0.0 : figxmax = 20.0 : figdx = 1.0
                figymin = 0.0 : figymax = 1.0 : figdy = 0.1
                sxjiku = "振動数 (Hz)"
            Case "L"
                figxmin = -2.0 : figxmax = 1.0 : figdx = 1.0
                figymin = -1.0 : figymax = 3.0 : figdy = 1.0
                sxjiku = "周期 (sec)"
        End Select
        df = 1.0 / dt / CDbl(nn)

        '画像書き出し
        kpt = 2
        For jj = 0 To 4
            Select Case jj
                Case 0
                    fnameD = wn0(icase - 1) & "_" & "figfs01.png"
                    For i = 0 To nd : datay(i) = fs01(i) : Next i
                    band = 0.0
                    comR = strcom1(icase - 1)
                Case 1
                    fnameD = wn0(icase - 1) & "_" & "figfs02.png"
                    For i = 0 To nd : datay(i) = fs02(i) : Next i
                    band = 0.0
                    comR = strcom2(icase - 1)
                Case 2
                    fnameD = wn0(icase - 1) & "_" & "figfsp1.png"
                    For i = 0 To nd : datay(i) = fsp1(i) : Next i
                    band = CDbl(ToolStripTextBox1.Text)
                    comR = strcom1(icase - 1)
                Case 3
                    fnameD = wn0(icase - 1) & "_" & "figfsp2.png"
                    For i = 0 To nd : datay(i) = fsp2(i) : Next i
                    band = CDbl(ToolStripTextBox1.Text)
                    comR = strcom2(icase - 1)
                Case 4
                    fnameD = wn0(icase - 1) & "_" & "figfspr.png"
                    For i = 0 To nd : datay(i) = fspr(i) : Next i
                    band = CDbl(ToolStripTextBox1.Text)
                    comR = strcom1(icase - 1) & "／" & strcom2(icase - 1)
            End Select
            Select Case jj
                Case 0 To 3
                    Select Case slog(icase - 1)
                        Case "N" : syjiku = "フーリエスペクトル"
                        Case "L" : syjiku = "フーリエスペクトル (gal*sec)"
                    End Select
                Case 4 : syjiku = "フーリエスペクトル比"
            End Select
            Select Case slog(icase - 1)
                Case "N"
                    For i = 0 To nd
                        datax(i) = fq(i)
                    Next i
                    fsmax = datay(0)
                    For i = 0 To nd
                        If fsmax <= datay(i) Then fsmax = datay(i)
                    Next i
                    For i = 0 To nd
                        datay(i) = datay(i) / fsmax
                    Next i
                Case "L"
                    For i = 1 To nd
                        datax(i) = Math.Log10(1.0 / fq(i))
                    Next i
                    datax(0) = datax(1) * 2.0
                    For i = 0 To nd
                        datay(i) = Math.Log10(datay(i))
                    Next i
                    fsmax = datay(0)
                    For i = 0 To nd
                        If fsmax <= datay(i) Then fsmax = datay(i)
                    Next i
                    fsmax = 10 ^ fsmax
            End Select

            PictureBox1.Size = New Size(kpt * HSIZE, kpt * VSIZE)
            PictureBox1.Visible = False
            bmp = New Bitmap(PictureBox1.Width, PictureBox1.Height)
            PictureBox1.Image = bmp
            g = Graphics.FromImage(PictureBox1.Image)
            g.FillRectangle(Brushes.White, 0, 0, PictureBox1.Width, PictureBox1.Height)
            Call PLOT(g, kpt, sxjiku, syjiku, figxmin, figxmax, figdx, figymin, figymax, figdy, _
                      kxi0, kxf0, kyi0, kyf0, nd, datax, datay, slog(icase - 1), slog(icase - 1), band, fsmax, comR)
            fnameD = System.IO.Path.GetDirectoryName(fnameR) & "\" & fnameD
            PictureBox1.Image.Save(fnameD, System.Drawing.Imaging.ImageFormat.Png)
            g.Dispose()
        Next jj
    End Sub


    Private Sub FFT(ByVal nn As Integer, ByRef xr() As Double, ByRef xi() As Double)

        Dim g As Integer : Dim h As Integer : Dim i As Integer : Dim j As Integer : Dim k As Integer
        Dim l As Integer : Dim m As Integer : Dim n As Integer : Dim p As Integer : Dim q As Integer
        Dim a As Double : Dim b As Double : Dim xd As Double
        Dim s() As Double
        Dim c() As Double

        n = nn
        ReDim s(CInt(n / 2))
        ReDim c(CInt(n / 2))
        i = 0 : j = 0 : k = 0 : l = 0 : p = 0 : h = 0 : g = 0 : q = 0
        m = CInt(System.Math.Log(CDbl(n)) / System.Math.Log(2.0) + 1.0)
        a = 0.0 : b = Math.PI * 2.0 / CDbl(n)
        For i = 0 To CInt(n / 2)
            s(i) = System.Math.Sin(a) : c(i) = System.Math.Cos(a) : a = a + b
        Next i
        l = n : h = 1
        For g = 1 To m
            l = CInt(l / 2) : k = 0
            For q = 1 To h
                p = 0
                For i = k To l + k - 1
                    j = i + l
                    a = xr(i) - xr(j) : b = xi(i) - xi(j)
                    xr(i) = xr(i) + xr(j) : xi(i) = xi(i) + xi(j)
                    If p = 0 Then
                        xr(j) = a : xi(j) = b
                    Else
                        xr(j) = a * c(p) + b * s(p) : xi(j) = b * c(p) - a * s(p)
                    End If
                    p = p + h
                Next i
                k = k + l + l
            Next q
            h = h + h
        Next g
        j = CInt(n / 2)
        For i = 1 To n - 1
            k = n
            If j < i Then
                xd = xr(i) : xr(i) = xr(j) : xr(j) = xd
                xd = xi(i) : xi(i) = xi(j) : xi(j) = xd
            End If
            k = CInt(k / 2)
            Do While j >= k
                j = j - k : k = CInt(k / 2)
                If k = 0 Then Exit Do
            Loop
            j = j + k
        Next i

    End Sub

    Private Sub IACC(ByVal nn As Integer, ByVal dt As Double, ByRef ddy() As Double, ByRef dy() As Double, ByRef y() As Double, _
                 ByRef ddymax As Double, ByRef dymax As Double, ByRef ymax As Double)

        '加速度時刻歴数値積分
        'nn:加速度時刻歴データ総数
        'dt    :時間間隔（入力値）
        'ddy() :加速度時刻歴（入力値）
        'dy()  :速度時刻歴（計算出力）
        'y()   :変位時刻歴（計算出力値）
        'ddymax:加速度最大値（計算出力値）
        'dymax :速度最大値（計算出力値）
        'ymax  :変位最大値（計算出力値）

        Dim i As Integer

        ddymax = 0.0
        dymax = 0.0
        ymax = 0.0

        dy(0) = 0.0
        y(0) = 0.0
        For i = 1 To nn - 1
            dy(i) = dy(i - 1) + (ddy(i - 1) + ddy(i)) * dt / 2.0
            y(i) = y(i - 1) + dy(i - 1) * dt + (ddy(i - 1) / 3.0 + ddy(i) / 6.0) * dt * dt
            If (ddymax < System.Math.Abs(ddy(i))) Then ddymax = System.Math.Abs(ddy(i))
            If (dymax < System.Math.Abs(dy(i))) Then dymax = System.Math.Abs(dy(i))
            If (ymax < System.Math.Abs(y(i))) Then ymax = System.Math.Abs(y(i))
        Next i

    End Sub

    Private Sub CRAC(ByVal nn As Integer, ByVal dt As Double, ByRef ddy() As Double, ByRef dy() As Double, ByRef y() As Double, _
                     ByVal ddymax As Double, ByVal dymax As Double, ByVal ymax As Double)

        '加速度時刻歴基線補正
        'nn:加速度時刻歴データ総数
        'dt    :時間間隔（入力値）
        'ddy() :加速度時刻歴（入力値・書換出力値）
        'dy()  :速度時刻歴（入力値）
        'y()   :変位時刻歴（入力値）
        'ddymax:加速度最大値（入力値）
        'dymax :速度最大値（入力値）
        'ymax  :変位最大値（入力値）

        Dim i As Integer
        Dim tt As Double
        Dim t As Double
        Dim sum As Double
        Dim a1 As Double
        Dim a0 As Double
        Dim acmax As Double
        Dim coef As Double

        tt = CDbl(nn - 1) * dt
        t = 0.0
        For i = 0 To nn - 1
            y(i) = y(i) * (3.0 * tt - 2.0 * t) * t * t
            t = t + dt
        Next i
        sum = (y(0) + y(nn - 1)) / 2.0
        For i = 1 To nn - 2
            sum = sum + y(i)
        Next i
        sum = sum * dt
        a1 = 28.0 / 13.0 / tt / tt * (2.0 * dy(nn - 1) - 15.0 / System.Math.Pow(tt, 5.0) * sum)
        a0 = dy(nn - 1) / tt - a1 / 2.0 * tt
        t = 0.0
        acmax = 0.0
        For i = 0 To nn - 1
            ddy(i) = ddy(i) - a0 - a1 * t
            If (acmax < System.Math.Abs(ddy(i))) Then acmax = System.Math.Abs(ddy(i))
            t = t + dt
        Next i
        coef = ddymax / acmax
        For i = 0 To nn - 1
            ddy(i) = ddy(i) * coef
        Next i

    End Sub

    Private Sub SWIN(ByVal nn As Integer, ByRef fs() As Double, ByVal df As Double, ByVal band As Double)
        'スペクトル平滑化
        'nn   ：時刻歴全数
        'fs() ：フーリエ・スペクトル
        'df   ：スペクトルの振動数間隔（Hz）
        'band ：バンド幅（Hz）
        'nfold：スペクトル値総数
        Dim w() As Double
        Dim g() As Double
        Dim g1() As Double
        Dim g2() As Double
        Dim tt As Double
        Dim udf As Double
        Dim dif As Double
        Dim s As Double
        Dim i As Integer
        Dim j As Integer
        Dim nfold As Integer
        Dim lmax As Integer
        Dim ll As Integer
        Dim ln As Integer
        Dim lt As Integer
        Dim le As Integer
        Dim pi As Double

        ReDim g(nn - 1)
        ReDim g1(nn - 1)
        ReDim g2(nn - 1)

        pi = Math.PI

        nfold = CInt(nn / 2) + 1

        If band > 0.0 Then
            tt = 1.0 / df
            udf = 280.0 / 151.0 / band * df
            lmax = CInt(2.0 / udf) + 1
            ReDim w(lmax - 1)

            If udf <= 0.5 Then
                w(0) = 0.75 * udf
                For i = 2 To lmax
                    dif = 0.5 * pi * CDbl(i - 1) * udf
                    w(i - 1) = w(0) * System.Math.Pow(System.Math.Sin(dif) / dif, 4.0)
                Next i
                g(0) = fs(0) * fs(0) / tt
                For i = 2 To nfold - 1
                    g(i - 1) = 2.0 * fs(i - 1) * fs(i - 1) / tt
                Next i
                g(nfold - 1) = fs(nfold - 1) * fs(nfold - 1) / tt
                ll = lmax * 2 - 1
                ln = ll - 1 + nfold
                lt = (ll - 1) * 2 + nfold
                le = lt - lmax + 1
                For i = 1 To lt
                    g1(i - 1) = 0.0
                Next i
                For i = 1 To nfold
                    g1(ll - 2 + i) = g(i - 1)
                Next i
                For i = lmax To le
                    s = w(0) * g1(i - 1)
                    For j = 2 To lmax
                        s = s + w(j - 1) * (g1(i - j) + g1(i + j - 2))
                    Next j
                    g2(i - 1) = s
                Next i
                For j = 2 To lmax
                    g2(ll + j - 2) = g2(ll + j - 2) + g2(ll - j)
                    g2(ln - j) = g2(ln - j) + g2(ln + j - 2)
                Next j
                For i = 1 To nfold
                    g(i - 1) = g2(ll - 2 + i)
                Next i
                fs(0) = System.Math.Sqrt(g(0) * tt)
                For i = 2 To nfold - 1
                    fs(i - 1) = System.Math.Sqrt(g(i - 1) * tt / 2.0)
                Next i
                fs(nfold - 1) = System.Math.Sqrt(g(nfold - 1) * tt)
            End If
        End If

    End Sub


    Private Sub PLOT(ByVal g As Graphics, ByVal kpt As Integer, ByVal sxjiku As String, ByVal syjiku As String, _
             ByVal xmin As Double, ByVal xmax As Double, ByVal dx As Double, _
             ByVal ymin As Double, ByVal ymax As Double, ByVal dy As Double, _
             ByVal kxi0 As Integer, ByVal kxf0 As Integer, ByVal kyi0 As Integer, ByVal kyf0 As Integer, _
             ByVal nd As Integer, ByRef datax() As Double, ByRef datay() As Double, _
             ByVal slogx As String, ByVal slogy As String, ByVal band As Double, ByVal fsmax As Double, _
             ByVal comR As String)

        Dim i As Integer
        Dim j As Integer
        Dim kxi As Integer : Dim kxf As Integer
        Dim kyi As Integer : Dim kyf As Integer
        Dim xx As Double : Dim yy As Double
        Dim kxx As Integer : Dim kyy As Integer
        Dim kxx1 As Integer : Dim kyy1 As Integer
        Dim kxx2 As Integer : Dim kyy2 As Integer
        Dim str As String
        Dim f As New Font("ＭＳ ゴシック", kpt * 16, FontStyle.Bold)
        Dim TextSize1 As New System.Drawing.SizeF
        Dim TextSize2 As New System.Drawing.SizeF

        kxi = kpt * kxi0 : kxf = kpt * kxf0 : kyi = kpt * kyi0 : kyf = kpt * kyf0

        '座標軸
        Dim LPen As New System.Drawing.Pen(System.Drawing.Color.Black)
        LPen.DashStyle = Drawing2D.DashStyle.Dot
        If slogx = "N" Then Call DRN_XJIKU(g, f, LPen, kpt, xmin, xmax, dx, kxi, kxf, kyi, kyf)
        If slogy = "N" Then Call DRN_YJIKU(g, f, LPen, kpt, ymin, ymax, dy, kxi, kxf, kyi, kyf)
        If slogx = "L" Then Call DRL_XJIKU(g, f, LPen, kpt, xmin, xmax, kxi, kxf, kyi, kyf)
        If slogy = "L" Then Call DRL_YJIKU(g, f, LPen, kpt, ymin, ymax, kxi, kxf, kyi, kyf)
        '枠線描画
        g.DrawRectangle(New Pen(Color.Black, 2), kxi, kyi, kxf - kxi, kyf - kyi)
        'ｙ軸名描画
        str = syjiku
        TextSize2 = g.MeasureString(str, f)
        TextSize1 = g.MeasureString("-1.0", f)
        kxx = CInt(kxi - kpt * 10 - TextSize1.Width - TextSize2.Height)
        kyy = CInt((kyi + kyf) / 2 + TextSize2.Width / 2)
        Call INC_STR(g, f, str, kxx, kyy, -90)
        'ｘ軸名描画
        str = sxjiku
        TextSize2 = g.MeasureString(str, f)
        kxx = CInt((kxi + kxf) / 2 - TextSize2.Width / 2)
        kyy = CInt(kyf + kpt * 10 + TextSize1.Height)
        Call INC_STR(g, f, str, kxx, kyy, 0)
        'データを線で連結
        xx = datax(0)
        yy = datay(0)
        If xx < xmin Then xx = xmin
        If xmax < xx Then xx = xmax
        If yy < ymin Then yy = ymin
        If ymax < yy Then yy = ymax
        kxx1 = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
        kyy1 = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
        For i = 1 To nd
            xx = datax(i)
            yy = datay(i)
            If xx < xmin Then xx = xmin
            If xmax < xx Then xx = xmax
            If yy < ymin Then yy = ymin
            If ymax < yy Then yy = ymax
            kxx2 = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            kyy2 = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            g.DrawLine(New Pen(Color.Blue, 2), kxx1, kyy1, kxx2, kyy2)
            kxx1 = kxx2
            kyy1 = kyy2
        Next i

        Dim nfp As Integer
        Dim kfp() As Integer
        ReDim kfp(nd - 1)

        '極大値となる周波数
        j = -1
        For i = 1 To nd - 1
            If (datay(i - 1) < datay(i)) And (datay(i) > datay(i + 1)) Then '極大値となる番号の検索
                j = j + 1 : kfp(j) = i
            End If
        Next i
        nfp = j

        Dim k As Integer
        Dim wx() As Double
        Dim wy() As Double
        ReDim wx(nfp)
        ReDim wy(nfp)
        For i = 0 To nfp
            wx(i) = datax(kfp(i))
            wy(i) = datay(kfp(i))
        Next i
        '大きい順の並び替え
        Call SORT(nfp, wx, wy)

        If 0.0001 < band Then
            f = New Font("ＭＳ ゴシック", kpt * 12, FontStyle.Italic)
            j = -1
            k = 0
            Do
                j = j + 1
                If nfp < j Then Exit Do
                xx = wx(j)
                yy = wy(j)
                If Math.Log10(0.05) <= xx Then
                    If xx <= xmax Then
                        k = k + 1
                        kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
                        kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
                        Select Case slogx
                            Case "N"
                                str = xx.ToString("0.000")
                            Case "L"
                                str = (10 ^ xx).ToString("0.000")
                        End Select
                        TextSize2 = g.MeasureString(str, f)
                        kxx = kxx - CInt(TextSize2.Height / 2)
                        kyy = kyy - 1 * kpt
                        Call INC_STR(g, f, str, kxx, kyy, -90)
                    End If
                End If
            Loop While k <= 10
        End If

        f = New Font("ＭＳ ゴシック", kpt * 16, FontStyle.Bold)
        str = "バンド幅：" & band.ToString("0.0") & " Hz"
        If band < 0.0001 Then str = "原波形"
        TextSize2 = g.MeasureString(str, f)
        g.DrawString(str, f, Brushes.Black, kxf - TextSize2.Width - 5 * kpt, kyi + 5 * kpt)
        If syjiku = "フーリエスペクトル" Or syjiku = "フーリエスペクトル (gal*sec)" Then
            str = "max:" & fsmax.ToString("0") & "(gal*sec)"
        End If
        If syjiku = "フーリエスペクトル比" Then str = "max:" & fsmax.ToString("0.000")
        TextSize2 = g.MeasureString(str, f)
        g.DrawString(str, f, Brushes.Black, kxf - TextSize2.Width - 5 * kpt, kyi - 25 * kpt)
        g.DrawString(comR, f, Brushes.Black, kxi + 5 * kpt, kyi - 25 * kpt)

        f.Dispose()

    End Sub


    Private Sub SORT(ByVal nd As Integer, ByRef xd() As Double, ByRef yd() As Double)
        Dim i As Integer
        Dim j As Integer
        Dim work As Double

        'ydの大きい順でのソート
        For i = 0 To nd - 1
            For j = i + 1 To nd
                If yd(i) < yd(j) Then
                    work = xd(i) : xd(i) = xd(j) : xd(j) = work
                    work = yd(i) : yd(i) = yd(j) : yd(j) = work
                End If
            Next j
        Next i

    End Sub


    Private Sub INC_STR(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal str As String, _
                        ByVal kxx As Integer, ByVal kyy As Integer, ByVal ang As Single)
        '軸名描画
        g.ScaleTransform(1.0, 1.0)                '横・縦の表示比率を設定
        g.TranslateTransform(kxx, kyy)            '表示位置の設定（表示位置を原点とする座標移動）
        g.RotateTransform(ang)                    '表示角度を指定
        g.DrawString(str, f, Brushes.Black, 0, 0) '描画実行
        g.ResetTransform()                        '単位行列にリセット
    End Sub


    Private Sub DRN_XJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal xmin As Double, ByVal xmax As Double, ByVal dx As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim ix As Integer
        Dim xx As Double
        Dim wv As Double
        Dim str As String
        Dim kxx As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '普通ｘ軸描画
        ix = CInt((xmax - xmin) / dx)
        For i = 0 To ix
            xx = xmin + CDbl(i) * dx
            kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            wv = xmin + CDbl(i) * dx
            str = wv.ToString("0")
            If CInt(dx * 1000.0) Mod 10 <> 0 Then str = wv.ToString("0.000")
            If CInt(dx * 1000.0) Mod 10 = 0 And CInt(dx * 100.0) Mod 10 <> 0 Then str = wv.ToString("0.00")
            If (CInt(dx * 1000.0) Mod 10 = 0 And CInt(dx * 100.0) Mod 10 = 0) And CInt(dx * 10.0) Mod 10 <> 0 Then str = wv.ToString("0.0")
            TextSize1 = g.MeasureString(str, f)
            g.DrawLine(LPen, kxx, kyi, kxx, kyf)
            g.DrawString(str, f, Brushes.Black, kxx - TextSize1.Width / 2, kyf + kpt * 3)
        Next i
    End Sub


    Private Sub DRN_YJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal ymin As Double, ByVal ymax As Double, ByVal dy As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim iy As Integer
        Dim yy As Double
        Dim wv As Double
        Dim str As String
        Dim kyy As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '普通ｙ軸描画
        iy = CInt((ymax - ymin) / dy)
        For i = 0 To iy
            yy = ymin + CDbl(i) * dy
            kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            wv = ymin + CDbl(i) * dy
            str = wv.ToString("0")
            If CInt(dy * 1000.0) Mod 10 <> 0 Then str = wv.ToString("0.000")
            If CInt(dy * 1000.0) Mod 10 = 0 And CInt(dy * 100.0) Mod 10 <> 0 Then str = wv.ToString("0.00")
            If (CInt(dy * 1000.0) Mod 10 = 0 And CInt(dy * 100.0) Mod 10 = 0) And CInt(dy * 10.0) Mod 10 <> 0 Then str = wv.ToString("0.0")
            TextSize1 = g.MeasureString(str, f)
            g.DrawLine(LPen, kxi, kyy, kxf, kyy)
            g.DrawString(str, f, Brushes.Black, kxi - TextSize1.Width - kpt * 2, kyy - TextSize1.Height / 2)
        Next i
    End Sub


    Private Sub DRL_XJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal xmin As Double, ByVal xmax As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim j As Integer
        Dim xx As Double
        Dim str As String
        Dim kxx As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '対数ｘ軸描画
        For i = CInt(xmin) To CInt(xmax) - 1
            For j = 1 To 9
                xx = System.Math.Log(CDbl(j) * System.Math.Pow(10.0, CDbl(i))) / System.Math.Log(10.0)
                kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
                g.DrawLine(LPen, kxx, kyi, kxx, kyf)
            Next j
        Next i
        For i = CInt(xmin) To CInt(xmax)
            xx = CDbl(i)
            kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            str = CStr(System.Math.Pow(10.0, CDbl(i)))
            TextSize1 = g.MeasureString(str, f)
            g.DrawString(str, f, Brushes.Black, kxx - TextSize1.Width / 2, kyf + kpt * 3)
        Next i
    End Sub


    Private Sub DRL_YJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal ymin As Double, ByVal ymax As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim j As Integer
        Dim yy As Double
        Dim str As String
        Dim kyy As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '対数ｙ軸描画
        For i = CInt(ymin) To CInt(ymax) - 1
            For j = 1 To 9
                yy = System.Math.Log(CDbl(j) * System.Math.Pow(10.0, CDbl(i))) / System.Math.Log(10.0)
                kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
                g.DrawLine(LPen, kxi, kyy, kxf, kyy)
            Next j
        Next i
        For i = CInt(ymin) To CInt(ymax)
            yy = CDbl(i)
            kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            str = CStr(System.Math.Pow(10.0, CDbl(i)))
            TextSize1 = g.MeasureString(str, f)
            g.DrawString(str, f, Brushes.Black, kxi - TextSize1.Width - kpt * 2, kyy - TextSize1.Height / 2)
        Next i
    End Sub

End Class