Option Explicit On
Option Strict On
Public Class Form1

    Private Sub ToolStripButton1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ToolStripButton1.Click
        Call main()
    End Sub


    Private Sub ToolStripButton2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ToolStripButton2.Click

        Dim fname2 As String = ""

        SaveFileDialog1.Filter = "*.bmp|*.bmp|" _
        & "*.jpg|*.jpg|" _
        & "*.png|*.png|" _
        & "*.wmf|*.wmf|" _
        & "*.tif|*.tif|" _
        & "*.gif|*.gif"

        If SaveFileDialog1.ShowDialog() = Windows.Forms.DialogResult.OK Then fname2 = SaveFileDialog1.FileName
        Select Case SaveFileDialog1.FilterIndex
            Case 1 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Bmp)
            Case 2 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Jpeg)
            Case 3 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Png)
            Case 4 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Wmf)
            Case 5 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Tiff)
            Case 6 : PictureBox2.Image.Save(fname2, System.Drawing.Imaging.ImageFormat.Gif)
        End Select

    End Sub


    Private Sub main()

        '作図用変数宣言
        Dim kpt As Integer    '拡大率（画面表示：1，ファイル保存：2）
        Dim HSIZE As Integer  '画像横寸法（px）
        Dim DHL As Integer    '画像左余白寸法：縦軸描画用（px）
        Dim DHR As Integer    '画像右余白寸法（px）
        Dim VSIZE As Integer  '画像縦寸法（px）
        Dim DVL As Integer    '画像下余白寸法：横軸描画用（px）
        Dim DVU As Integer    '画像上余白寸法（px）
        Dim sxjiku As String  'ｘ軸名（単位含む）
        Dim xmin As Double    'ｘ軸最小値
        Dim xmax As Double    'ｘ軸最大値
        Dim dx As Double      'ｘ軸増分
        Dim slogx As String   'ｘ軸の種類（L：対数，N：普通）
        Dim syjiku As String  'ｙ軸名（単位含む）
        Dim ymin As Double    'ｙ軸最小値
        Dim ymax As Double    'ｙ軸最大値
        Dim dy As Double      'ｙ軸増分
        Dim slogy As String   'ｙ軸の種類（L：対数，N：普通）
        Dim kxi0 As Integer
        Dim kxf0 As Integer
        Dim kyi0 As Integer
        Dim kyf0 As Integer
        Dim thePicBox As PictureBox = PictureBox1
        Dim bmp As Bitmap
        Dim g As Graphics

        'データ格納用変数宣言
        Dim datax() As Double 'データｘ値
        Dim datay() As Double 'データｙ値
        Dim nd As Integer     'データ数（入力はデータ数，プログラム上数値はデータ数−１）

        'データ入力用変数宣言
        Dim sr As System.IO.StreamReader
        Dim dat As String
        Dim sbuf() As String
        Dim delim() As Char = {","c}
        Dim fname1 As String = ""

        Dim i As Integer
        Dim pi As Double = Math.PI

        'データ読み込み
        OpenFileDialog1.InitialDirectory = My.Computer.FileSystem.CurrentDirectory
        If OpenFileDialog1.ShowDialog() = Windows.Forms.DialogResult.OK Then fname1 = OpenFileDialog1.FileName
        sr = New System.IO.StreamReader(fname1, System.Text.Encoding.Default)
        dat = sr.ReadLine()
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : sxjiku = sbuf(0) : syjiku = sbuf(1)
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : HSIZE = CInt(sbuf(0)) : DHL = CInt(sbuf(1)) : DHR = CInt(sbuf(2))
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : VSIZE = CInt(sbuf(0)) : DVL = CInt(sbuf(1)) : DVU = CInt(sbuf(2))
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : xmin = CDbl(sbuf(0)) : xmax = CDbl(sbuf(1)) : dx = CDbl(sbuf(2)) : slogx = sbuf(3)
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : ymin = CDbl(sbuf(0)) : ymax = CDbl(sbuf(1)) : dy = CDbl(sbuf(2)) : slogy = sbuf(3)
        dat = sr.ReadLine() : sbuf = dat.Split(delim) : nd = CInt(sbuf(0)) - 1
        i = 0
        ReDim datax(nd)
        ReDim datay(nd)
        Do While sr.Peek() >= 0
            dat = sr.ReadLine()
            sbuf = dat.Split(delim)
            datax(i) = CDbl(sbuf(0))
            datay(i) = CDbl(sbuf(1))
            i = i + 1
        Loop
        sr.Close()
        nd = i - 1

        'プロット領域定義
        kxi0 = DHL
        kxf0 = HSIZE - DHR
        kyi0 = DVU
        kyf0 = VSIZE - DVL
        Console.WriteLine(kxi0.ToString & "  " & kxf0.ToString & "  " & kyi0.ToString & "  " & kyf0.ToString)

        '対数値処理
        If slogx = "L" Then
            For i = 0 To nd
                If datax(i) < System.Math.Pow(10.0, xmin) Then datax(i) = System.Math.Pow(10.0, xmin)
                datax(i) = System.Math.Log10(datax(i))
            Next i
        End If
        If slogy = "L" Then
            For i = 0 To nd
                If datay(i) < System.Math.Pow(10.0, ymin) Then datay(i) = System.Math.Pow(10.0, ymin)
                datay(i) = System.Math.Log10(datay(i))
            Next i
        End If

        For i = 0 To 1
            Select Case i
                Case 0 '画面描画
                    kpt = 1
                    thePicBox = PictureBox1
                    thePicBox.Visible = True
                Case 1 '画像書き出し
                    kpt = 2
                    thePicBox = PictureBox2
                    thePicBox.Visible = False
            End Select
            thePicBox.Size = New Size(kpt * HSIZE, kpt * VSIZE)
            bmp = New Bitmap(thePicBox.Width, thePicBox.Height)
            thePicBox.Image = bmp
            g = Graphics.FromImage(thePicBox.Image)
            g.FillRectangle(Brushes.White, 0, 0, thePicBox.Width, thePicBox.Height)
            Call PLOT(g, kpt, sxjiku, syjiku, xmin, xmax, dx, ymin, ymax, dy, kxi0, kxf0, kyi0, kyf0, nd, datax, datay, slogx, slogy)
            g.Dispose()
        Next i

        PictureBox1.Left = 0
        PictureBox1.Top = ToolStrip1.Height
        Me.ClientSize = New Size(PictureBox1.Width, PictureBox1.Height + ToolStrip1.Height)

    End Sub


    Private Sub PLOT(ByVal g As Graphics, ByVal kpt As Integer, ByVal sxjiku As String, ByVal syjiku As String, _
                 ByVal xmin As Double, ByVal xmax As Double, ByVal dx As Double, _
                 ByVal ymin As Double, ByVal ymax As Double, ByVal dy As Double, _
                 ByVal kxi0 As Integer, ByVal kxf0 As Integer, ByVal kyi0 As Integer, ByVal kyf0 As Integer, _
                 ByVal nd As Integer, ByRef datax() As Double, ByRef datay() As Double, _
                 ByVal slogx As String, ByVal slogy As String)

        Dim i As Integer
        Dim kxi As Integer : Dim kxf As Integer
        Dim kyi As Integer : Dim kyf As Integer
        Dim xx As Double : Dim yy As Double
        Dim kxx As Integer : Dim kyy As Integer
        Dim kxx1 As Integer : Dim kyy1 As Integer
        Dim kxx2 As Integer : Dim kyy2 As Integer
        Dim str As String
        Dim dc As Integer
        Dim f As New Font("ＭＳ ゴシック", kpt * 10)
        Dim TextSize1 As New System.Drawing.SizeF
        Dim TextSize2 As New System.Drawing.SizeF

        kxi = kpt * kxi0 : kxf = kpt * kxf0 : kyi = kpt * kyi0 : kyf = kpt * kyf0

        '座標軸
        Dim LPen As New System.Drawing.Pen(System.Drawing.Color.Black)
        LPen.DashStyle = Drawing2D.DashStyle.Dot
        If slogx = "N" Then Call DRN_XJIKU(g, f, LPen, kpt, xmin, xmax, dx, kxi, kxf, kyi, kyf)
        If slogy = "N" Then Call DRN_YJIKU(g, f, LPen, kpt, ymin, ymax, dy, kxi, kxf, kyi, kyf)
        If slogx = "L" Then Call DRL_XJIKU(g, f, LPen, kpt, xmin, xmax, kxi, kxf, kyi, kyf)
        If slogy = "L" Then Call DRL_YJIKU(g, f, LPen, kpt, ymin, ymax, kxi, kxf, kyi, kyf)
        '枠線描画
        g.DrawRectangle(New Pen(Color.Black, 2), kxi, kyi, kxf - kxi, kyf - kyi)
        'ｙ軸名描画
        str = syjiku
        TextSize2 = g.MeasureString(str, f)
        TextSize1 = g.MeasureString("-1.0", f)
        kxx = CInt(kxi - kpt * 10 - TextSize1.Width - TextSize2.Height)
        kyy = CInt((kyi + kyf) / 2 + TextSize2.Width / 2)
        Call INC_STR(g, f, str, kxx, kyy, -90)
        'ｘ軸名描画
        str = sxjiku
        TextSize2 = g.MeasureString(str, f)
        kxx = CInt((kxi + kxf) / 2 - TextSize2.Width / 2)
        kyy = CInt(kyf + kpt * 10 + TextSize1.Height)
        Call INC_STR(g, f, str, kxx, kyy, 0)
        'データプロット
        dc = kpt * 5
        For i = 0 To nd
            xx = datax(i)
            yy = datay(i)
            kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin)) - CInt(dc / 2)
            kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin)) - CInt(dc / 2)
            g.DrawEllipse(New Pen(Color.Red, 1), kxx, kyy, dc, dc)
        Next
        'データを線で連結
        xx = datax(0)
        yy = datay(0)
        kxx1 = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
        kyy1 = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
        For i = 1 To nd
            xx = datax(i)
            yy = datay(i)
            kxx2 = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            kyy2 = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            g.DrawLine(New Pen(Color.Blue, 1), kxx1, kyy1, kxx2, kyy2)
            kxx1 = kxx2
            kyy1 = kyy2
        Next i
        f.Dispose()

    End Sub


    Private Sub INC_STR(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal str As String, _
                        ByVal kxx As Integer, ByVal kyy As Integer, ByVal ang As Single)
        '軸名描画
        g.ScaleTransform(1.0, 1.0)                '横・縦の表示比率を設定
        g.TranslateTransform(kxx, kyy)            '表示位置の設定（表示位置を原点とする座標移動）
        g.RotateTransform(ang)                    '表示角度を指定
        g.DrawString(str, f, Brushes.Black, 0, 0) '描画実行
        g.ResetTransform()                        '単位行列にリセット
    End Sub


    Private Sub DRN_XJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal xmin As Double, ByVal xmax As Double, ByVal dx As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim ix As Integer
        Dim xx As Double
        Dim wv As Double
        Dim str As String
        Dim kxx As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '普通ｘ軸描画
        ix = CInt((xmax - xmin) / dx)
        For i = 0 To ix
            xx = xmin + CDbl(i) * dx
            kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            wv = xmin + CDbl(i) * dx
            str = wv.ToString("0")
            If CInt(dx * 1000.0) Mod 10 <> 0 Then str = wv.ToString("0.000")
            If CInt(dx * 1000.0) Mod 10 = 0 And CInt(dx * 100.0) Mod 10 <> 0 Then str = wv.ToString("0.00")
            If (CInt(dx * 1000.0) Mod 10 = 0 And CInt(dx * 100.0) Mod 10 = 0) And CInt(dx * 10.0) Mod 10 <> 0 Then str = wv.ToString("0.0")
            TextSize1 = g.MeasureString(str, f)
            g.DrawLine(LPen, kxx, kyi, kxx, kyf)
            g.DrawString(str, f, Brushes.Black, kxx - TextSize1.Width / 2, kyf + kpt * 3)
        Next i
    End Sub


    Private Sub DRN_YJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal ymin As Double, ByVal ymax As Double, ByVal dy As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim iy As Integer
        Dim yy As Double
        Dim wv As Double
        Dim str As String
        Dim kyy As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '普通ｙ軸描画
        iy = CInt((ymax - ymin) / dy)
        For i = 0 To iy
            yy = ymin + CDbl(i) * dy
            kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            wv = ymin + CDbl(i) * dy
            str = wv.ToString("0")
            If CInt(dy * 1000.0) Mod 10 <> 0 Then str = wv.ToString("0.000")
            If CInt(dy * 1000.0) Mod 10 = 0 And CInt(dy * 100.0) Mod 10 <> 0 Then str = wv.ToString("0.00")
            If (CInt(dy * 1000.0) Mod 10 = 0 And CInt(dy * 100.0) Mod 10 = 0) And CInt(dy * 10.0) Mod 10 <> 0 Then str = wv.ToString("0.0")
            TextSize1 = g.MeasureString(str, f)
            g.DrawLine(LPen, kxi, kyy, kxf, kyy)
            g.DrawString(str, f, Brushes.Black, kxi - TextSize1.Width - kpt * 2, kyy - TextSize1.Height / 2)
        Next i
    End Sub


    Private Sub DRL_XJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal xmin As Double, ByVal xmax As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim j As Integer
        Dim xx As Double
        Dim str As String
        Dim kxx As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '対数ｘ軸描画
        For i = CInt(xmin) To CInt(xmax) - 1
            For j = 1 To 9
                xx = System.Math.Log(CDbl(j) * System.Math.Pow(10.0, CDbl(i))) / System.Math.Log(10.0)
                kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
                g.DrawLine(LPen, kxx, kyi, kxx, kyf)
            Next j
        Next i
        For i = CInt(xmin) To CInt(xmax)
            xx = CDbl(i)
            kxx = kxi + CInt((xx - xmin) * (kxf - kxi) / (xmax - xmin))
            str = CStr(System.Math.Pow(10.0, CDbl(i)))
            TextSize1 = g.MeasureString(str, f)
            g.DrawString(str, f, Brushes.Black, kxx - TextSize1.Width / 2, kyf + kpt * 3)
        Next i
    End Sub


    Private Sub DRL_YJIKU(ByVal g As Graphics, ByVal f As System.Drawing.Font, ByVal LPen As System.Drawing.Pen, _
                          ByVal kpt As Integer, _
                          ByVal ymin As Double, ByVal ymax As Double, _
                          ByVal kxi As Integer, ByVal kxf As Integer, _
                          ByVal kyi As Integer, ByVal kyf As Integer)
        Dim i As Integer
        Dim j As Integer
        Dim yy As Double
        Dim str As String
        Dim kyy As Integer
        Dim TextSize1 As New System.Drawing.SizeF

        '対数ｙ軸描画
        For i = CInt(ymin) To CInt(ymax) - 1
            For j = 1 To 9
                yy = System.Math.Log(CDbl(j) * System.Math.Pow(10.0, CDbl(i))) / System.Math.Log(10.0)
                kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
                g.DrawLine(LPen, kxi, kyy, kxf, kyy)
            Next j
        Next i
        For i = CInt(ymin) To CInt(ymax)
            yy = CDbl(i)
            kyy = kyf - CInt((yy - ymin) * (kyf - kyi) / (ymax - ymin))
            str = CStr(System.Math.Pow(10.0, CDbl(i)))
            TextSize1 = g.MeasureString(str, f)
            g.DrawString(str, f, Brushes.Black, kxi - TextSize1.Width - kpt * 2, kyy - TextSize1.Height / 2)
        Next i
    End Sub

End Class